########################################################################
### FILE:	toggles.mod
### PURPOSE:	Control various toggles (door, lamp, led, etc)
### AUTHORS:	Tor Slettnes
### SCOPE:	Top Level
###
### Copyrights (C) 2010 Life Technologies.  All rights reserved.
########################################################################

### Motion
    STATE:NEW Motion:Allowed -requires=Instrument:Safe

### Front Door, Tank Drawer
    STATe:NEW Interlock:Defeated
    STATe:NEW FrontDoor:Locked
    STATe:NEW FrontDoor:Open
    STATe:NEW TankDrawer:Open
    STATe:NEW TankDrawer:Locked
    STATe:NEW ReagentDrawer:Open
    STATe:NEW SyringeCover:Open

    STATe:DEPendency+ Instrument:Safe -requires=FrontDoor:Locked -conflicts=FrontDoor:Open
#   STATe:DEPendency+ Instrument:Safe -conflicts=ReagentDrawer:Open
#   STATe:DEPendency+ Instrument:Safe -conflicts=SyringeCover:Open

    STATe:DEPendency+ Instrument:Initialized -conflicts=ReagentDrawer:Open


    STATE:TRIGGer+ -states=FrontDoor:Locked -edge=Clear Home <quote>
       IF $(STATE? -errorState=True Instrument:Online) <quote>
           INFO "Parking objective, arm"
           STAGE:RESUME
           TRY 'FLAG -asynchronous Objective  "STAGE:PARK"' PASS
           TRY 'FLAG -asynchronous Robot "FLU:ARM:PARK"' PASS

           TRY 'SYNC Objective' PASS

           INFO "Bringing out stage"
           TRY 'FLAG -asynchronous Stage "STAGE:PARK"' PASS
           TRY 'SYNC Robot' PASS
           TRY 'SYNC Stage' PASS
       </quote>
    </quote>

    STATe:TRIGger+ -states=FrontDoor:Open -edge=Set ImplicitUnlock <quote>
       STATe= FrontDoor:Locked False
    </quote>

    STATe:TRIGger+ -states=FrontDoor:Open -edge=Error ImplicitError <quote>
       STATe= FrontDoor:Locked False -skipTriggers
    </quote>


### Door Control

    DEFine DOOR $action$ <quote>
       UNLess $(STATe? -errorState=False Instrument:Online) <quote>
          ERRor -id=Offline "Instrument is not online, unable to control door"
       </quote>

       TRY <quote>
          SET lock $[ ["unlock", "lock"].index("$action$".lower()) ]
       </quote> <quote.except>
          ERRor -id=InvalidAction "'action' must be one of 'lock' or 'unlock'"
       </quote.except>

       IF $[ ${lock} and $(STATe:SETTing? -errorState=False FrontDoor:Open) ] <q.if>
          ERRor -id=DoorOpen "Close the front door prior to locking it"
       </q.if>

       :STATe:SETTing FrontDoor:Locked ${lock}
    </quote>


    DESCribe DOOR <quote>
       Lock or unlock the instrument front door.
    </quote>


    DEFine DOOR? <quote>
       SET open   $(STATe:SETTing? FrontDoor:Open)
       SET locked $(STATe:SETTing? FrontDoor:Locked)

       IF $[ "/error/" in "/${open}/${locked}/".lower() ] \
          RETurn Error
       ELIF ${open} \
          RETurn Open
       ELIF ${locked} \
          RETurn Locked
       ELSE \
          RETurn Closed
    </quote>

    DESCribe DOOR? <quote>
        Return the current state of the front door: Open, Closed, or Locked.
    </quote>


### Tank Drawer control
    STATe:TRIGger+ -states=TankDrawer:Open -edge=Set ImplicitUnlock <quote>
       STATe= TankDrawer:Locked False
    </quote>

#    STATe:TRIGger+ -states=TankDrawer:Open -edge=Clear ImplicitLock <quote>
#       IF $[ ("$previousValue$" == "Error") and $(STATE? -errorState=False SystemLiquid:Installed) ] <quote>
#           INFO "Tank Drawer Open state changed from $previousValue$ to $value$ -- locking"
#           STATE= TankDrawer:Locked True -skipTriggers
#       </quote>
#    </quote>

    STATe:TRIGger+ -states=TankDrawer:Open -edge=Error ImplicitError <quote>
       STATe= TankDrawer:Locked False -skipTriggers
    </quote>


    DEFine TankDRAWer $action$ <quote>
       UNLess $(STATe? -errorState=True Instrument:Online) <quote>
          ERRor -id=Offline "Instrument is not online, unable to control tank drawer"
       </quote>

       TRY <quote>
          SET lock $[ ["unlock", "lock"].index("$action$".lower()) ]
       </quote> <quote.except>
          ERRor -id=InvalidAction "'action' must be one of 'lock' or 'unlock'"
       </quote.except>

       IF $[ ${lock} and $(STATe:SETTing? -errorState=False TankDrawer:Open) ] <q.if>
          ERRor -id=DrawerOpen "Close the tank drawer prior to locking it"
       </q.if>

       :STATe:SETTing TankDrawer:Locked ${lock}
    </quote>


    DESCribe TankDRAWer <quote>
       Lock or unlock the instrument tank drawer.
    </quote>


    DEFine TankDRAWer? <quote>
       SET open   $(STATe:SETTing? TankDrawer:Open)
       SET locked $(STATe:SETTing? TankDrawer:Locked)

       IF $[ "/error/" in "/${open}/${locked}/".lower() ] \
          RETurn Error
       ELIF ${open} \
          RETurn Open
       ELIF ${locked} \
          RETurn Locked
       ELSE \
          RETurn Closed
    </quote>

    DESCribe TankDRAWer? <quote>
        Return the current state of the tank drawer: Open, Closed, or Locked.
    </quote>


### Reset survey data 
    STATE:TRIGGER+ -immediate -states=ReagentDrawer:Open -edge=Clear ClearSurvey <quote>
        INFO "Clearing survey data..."
        SURVey~ *
    </quote>

    STATE:TRIGGER+ -immediate -states=FrontDoor:Open -edge=Clear ClearSurvey <quote>
        INFO "Clearing survey data in TMAX/TFE..."
        SURVey~ TMAX TFE
    </quote>


### Xenon Lamp
    STATE:NEW Lamp:On
    STATE:DEPendency+ Imaging:Ready -requires=Lamp:On

    DEFINE LAMP $state$ <quote>
       UNLess $(STATe? -errorState=False Instrument:Online) <quote>
          ERRor -id=Offline "Instrument is offline, unable to control lamp"
       </quote>

       TRY <quote.try>
           STATe= Lamp:On $state$
       </quote.try> <quote.except>
           ERRor -id=$error$ $arguments$ "$message$"
       </quote.except>
    </quote>

    DEScribe LAMP <quote>
        Turn lamp on or off
    </quote>

    DEFine LAMP? <quote>
        RETurn $(FILTER? -mask=$(STATE? Lamp:On) -inputs=False,True,Error -outputs=Off,On,Error)
    </quote>

    DEScribe LAMP? <quote>
        Return the state of the lamp: 'On' or 'Off'
    </quote>