########################################################################
### FILE:	runcontrol.mod
### PURPOSE:	Interface for defining/running protocols
###             (procedures, stages, programs, legs)
### SCOPE:	"FlowChip<n>" branches
###
### Copyrights (C) 2010 Life Technologies.  All rights reserved.
########################################################################

########################################################################
### MACRO:	STARt, STOP
### PURPOSE:	Start/stop instrument subsystems

VARiable START ""

DEFine STARt <quote>
   RUN ${START}
</quote>


DESCribe STARt <quote>
    Activate instrument subsystems
</quote>

VARiable STOP ""

DEFine STOP <quote>
   RUN ${STOP}
</quote>


DESCribe STOP <quote>
    Deactivate instrument subsystems
</quote>





########################################################################
### PROCedure support

ALIAS PROCedure MACRo+ -inline -asynchronous -replaceExisting


DEFine -asynchronous RUNPROC $name$ $args* <quote>
    SET culprits $(:STATe:CULPrits? FlowChip${FC}:Ready)
    IF ${#culprits} <quote>
        ERRor -id=NotReady -procedure=$name$ \
              "Not ready to run procedure '$name$' due to these conditions(s): ${culprits}"
    </quote>


    TRY <quote.try>
        :STATe= FlowChip${FC}:Running True

        TRACKer+ RUNTRACKER "$name$" $args*
        RUNTRACKER:TRACK Step    RunProc '"$name$" -step=$index -state=Running'
        RUNTRACKER:TRACK Paused  RunProc '"$name$" -step=$index -state=Paused'
        RUNTRACKER:TRACK Aborted RunProc '"$name$" -step=$index -state=Aborted'

        StartProc "$name$"
        PROCSTATE "$name$" Started $args*
        
	RUNTRACKER:RUN

        TRACKer- -ignoreMissing RUNTRACKER
	PROCSTATE "$name$" Completed
    </quote.try> <quote.except1>
        TRACKer- -ignoreMissing RUNTRACKER

	IF ${#RunControl:-} <quote.stopped>
	    PROCSTATE "$name$" ${RunControl}
	</quote.stopped>
	ELSE <quote.error>
            SET ERRID   ${error}
            SET ERRARGS ${arguments}
            SET ERRMSG  ${message}
	    PROCSTATE "$name$" Failed ${text}
	</quote.error>
        USE Robot
        TRY :FLUidics:HOME PASS
        TRY :FLUidics:ARM:HomeSyringe PASS
        CLEARLOCKS
        ResumeImaging
        RAMP -asynchronous 25.0 
    </quote.except1> <quote.except2>
        CLEARLOCKS
	WARN "Failed to clean up after failure: ${text}"
        WARN "Original error: [${ERRID}] ${ERRARGS} ${ERRMSG}"
    </quote.except2>

    TRY <quote.try>
        EndProc "$name$"
    </quote.try> <quote.except>
        WARN "Failed to stop after run: ${text}"
        CLEARLOCKS
    </quote.except>

    :STATe= FlowChip${FC}:Running False
    PUBlish RunProc '"$name$"' Ended

    IF ${#ERRID:-} "ERRor -id=${ERRID} ${ERRARGS} \${ERRMSG}"
</quote>


DEFINT STARTPROC $name$ <quote>
    VAR- -ignoreMissing RunControl
    VAR Procedure "$name$"
    START
</quote>


DEFINT ENDPROC $name$ <quote>
    STOP
    VAR- -ignoreMissing Procedure

    SET locks $(LOCK*)
    PUBLISH Info "Locks held after end of \"$name$\": ${locks:-(None)}"
</quote>


DEFINT PROCSTATE $name$ $state$ $args* <quote>
    VAR PROCSTATE '"$name$" $state$ $args*'
    PUBLish RunProc "${PROCSTATE}"
</quote>


########################################################################
### Client interface to get/set run state

DEFine RUNPROC? <quote>
    TRY <quote.try>
       RETURN $(RUNTRACKER:TRACK?)
    </quote.try> <quote.except>
       RETURN "(None)"
    </quote.except>
</quote>

DEFine LASTPROC? <quote>
    TRY <quote.try>
	RETURN $(RUNRACKER:TRACK?)
    </quote.try> <quote.except>
	RETURN ${PROCSTATE:--}
    </quote.except>
</quote>

DEFine CLEARPROC <quote>
    VAR- -ignoreMissing PROCSTATE
</quote>

DEFine PAUSEPROC $name$= $atStep$= <quote>
    TRY <quote.try>
	RUNTRACKER:PAUSE $atStep$
    </quote.try> <quote.except>
        ERRor -id=NotRunning "No procedure is currently running"
    </quote.except>
</quote>

DEFine RESUMEPROC $name$= $atStep$= <quote>
    TRY <quote.try>
        RUNTRACKER:RESUME $atStep$
    </quote.try> <quote.except>
        ERRor -id=NotRunning "No procedure is currently running"
    </quote.except>
</quote>

DEFine ABORTPROC $name$= $atStep$= <quote>
    TRY <quote.try>
        VAR RunControl Aborted
	RUNTRACKER:ABORT $atStep$
    </quote.try> <quote.except>
        ERRor -id=NotRunning "No procedure is currently running"
    </quote.except>
</quote>

DEFINE -asynchronous PAUSERUN <quote>
    ResumeImaging
#    ITERate -key=arm $(:FLUidics:ARM*) <iterate>
#        :FLUidics:${arm}:HOME -prehome
#        :FLUidics:${arm}:PARK
#    </iterate>
</quote>

DESCribe PAUSERUN <quote>
    Inform the Instrument Server that the fluidics run has paused.
    This allows the IS to tend to pending operations such as to resume imaging.
</quote>

########################################################################
### Misc. functions

DEFine TIMER $name$ $timeout$ <define>
    VAR Timer-$name$ $[ int($timeout$) ]
    SET delay        $[ $timeout$ - int($timeout$) ]

    FLAG -asynchronous '$name$' <flag>
        SCHedule+ "FlowChip${FC}-Timer-$name$" -replaceExisting -counter=remain -interval=1 -step=-1 \
                  -start=${Timer-$name$} -count=${Timer-$name$} -delay=${delay} <schedule>
           VARiable Timer-$name$ $[ $remain$ - 1 ]
           PUBLish Timer "$name$" -remaining=$remain$
        </schedule>
        WAIT $timeout$
        SCHedule- -ignoreMissing "FlowChip${FC}-Timer-$name$"
        VARiable- -ignoreMissing Timer-$name$
        PUBLish   Timer "$name$" -remaining=0
    </flag>
</define>

ALIas- -ignoreMissing SYNChronize
DEFine SYNChronize $name$ <define>
    :IDLE:WORK -skipWait ${FlowChip${FC}-Timer-$name$:-0}
    FLAG- -ignoreMissing '$name$'
</define>


DEFine COUNT? $delimiter$="," $match$ $list$="" <quote>
    SET count 0
    ITERate -key=match -delimiter="$delimiter$" "$match$" <quote.iterate>
        ADDValue count $[ "$list$".lower().split("$delimiter$").count("${match}".lower()) ]
    </quote.iterate>
    RETurn ${count}
</quote>




### Resource allocation commands
ALIAS PauseIMAGing  :PauseImaging
ALIAS ResumeIMAGing :ResumeImaging
ALIAS USE           :ACQuisition+ -owner=FlowChip${FC} -reentrant
ALIAS RELEASE       :ACQuisition- -owner=FlowChip${FC} -ignoreMissing
ALIAS CLEARLOCKS    :ACQuisition~ -owner=FlowChip${FC}
ALIAS LOCK*         :ACQuisition* -owner=FlowChip${FC}

### Do not implicitly resume imaging at end of script, unless script fails (per Joon, Mar 21, 2011).
#PREPend STOP "\n\tResumeImaging"

:STATe:NEW FlowChip${FC}:Running 
:STATe:NEW FlowChip${FC}:Ready -requires=Instrument:Initialized -conflicts=FlowChip${FC}:Running