########################################################################
### FILE:	hwstates.mod
### PURPOSE:	Handle hardware (FCB/ACB) state changes
### CONTEXT:	"LLAC:" branch
###
### Copyrights (C) 2011 Life Technologies. All rights reserved
########################################################################


### Add event handlers for states
    DEFINT EVENTS+ $branch$ $node$ $specfile$ <q.define>
        :LLAC:EVENT+ -replaceExisting $branch$-Sensor -id=0x8220 -idMask=0xFFFE -source=$node$ <q.event>
            SET index $23u
            SET state $(CONF? -ignoreMissing $specfile$ SensorStates ${index})

            IF $[ "${state}".startswith("!") ] <q.if>
                 SET value $[ $id != 0x8220 ]
                 SET state ${state:1}
            </q.if> 
            ELSE <q.else>
                 SET value $[ $id == 0x8220 ]
            </q.else>

            IF ${#state} <q.if>
                :STATe:SETTing -createMissing ${state} ${value}
            </q.if>
        </q.event>

        :LLAC:EVENT+ -replaceExisting $branch$-Sensor-Error -id=0x8222 -idMask=0xFFFE -source=$node$ <q.event>
            SET index  $23u
            SET state  $[ "$(CONF? -ignoreMissing $specfile$ SensorStates ${index})".lstrip("!") ]

            IF ${#state} <q.exists>
                INFO "State ${state} is now in error"
                :STATe:ERRor= ${state} $device.$[ "$id"[2:] ] "$text"
            </q.exists>
        </q.event>


	:LLAC:EVENT+ -replaceExisting $branch$-Solenoid-Disable -id=0x81AB -source=$node$ <q.event>
            SET index  $23u
            SET state  $(CONF? -ignoreMissing $specfile$ SolenoidStates ${index})

            IF ${#state} <q.if>
                INFO "Got disabled event from solenoid #${index}; clearing state ${state}"
                :STATE= ${state} False
            </q.if>
        </q.event>


	:LLAC:EVENT+ -replaceExisting $branch$-Solenoid-Timeout -id=0x81B2 -source=$node$ <q.event>
            SET index  $23u
            SET state  $(CONF? -ignoreMissing $specfile$ SolenoidStates ${index})

            IF ${#state} <q.if>
                INFO "Got timeout from solenoid #${index}; clearing state ${state}"
                :STATE= ${state} False
            </q.if>
        </q.event>

	:LLAC:EVENT+ -replaceExisting $branch$-Solenoid-On -id=0x81B3 -source=$node$ <q.event>
            SET index  $23u
            SET state  $(CONF? -ignoreMissing $specfile$ SolenoidStates ${index})

            IF ${#state} <q.if>
                INFO "Got ON event from solenoid #${index}; setting state ${state}"
                :STATE= ${state} True
            </q.if>
        </q.event>

	:LLAC:EVENT+ -replaceExisting $branch$-Solenoid-Off -id=0x81B4 -source=$node$ <q.event>
            SET index  $23u
            SET state  $(CONF? -ignoreMissing $specfile$ SolenoidStates ${index})

            IF ${#state} <q.if>
                INFO "Got OFF event from solenoid #${index}; clearing state ${state}"
                :STATE= ${state} False
            </q.if>
        </q.event>
    </q.define>


### Remove event handlers for states
    DEFINT EVENTS- $branch$ <q.define>
        :LLAC:EVENt- -ignoreMissing $branch$-Sensor-Error
        :LLAC:EVENt- -ignoreMissing $branch$-Sensor
    </q.define>


### Set values for states
    DEFINT STATE+ $allows$='' $prevents$='' $state$ $register$='' <q.define>
        UNLess $(:STATe:EXISTS? $state$) ':STATE:NEW $state$'

        IF $[ "$register$" != "" ] <q.if>
            :STATe:SETTing $state$ $($register$)
            APPend -create UpdateStates "\n\t:STATe:SETTing $state$ \$($register$)"
        </q.if>

        ITERate -key=dep -delimiter="," "$allows$" <q.iterate>
            IF ${#dep} ':STATe:DEPendency+ -replaceExisting ${dep} -requires=$state$'
        </q.iterate>

        ITERate -key=dep -delimiter="," "$prevents$" <q.iterate>
            IF ${#dep} ':STATe:DEPendency+ -replaceExisting ${dep} -conflicts=$state$'
        </q.iterate>
    </q.define>


### Clear all states
    DEFINT STATE~ <q.define>
        VAR- -ignoreMissing UpdateStates
    </q.define>


### Method to update all state values
    DEFINT UPDATESTATES <q.define>
        RUN ${UpdateStates:-}
    </q.define>