########################################################################
### FILE:       fluidicsarm.mod
### PURPOSE:    Composite commands for FLUidics:ARMx branches
### SCOPE:      "FLUidics:ARM:" branch.
###
### Copyrights (C) 2010-2011 Life Technologies.  All rights reserved.
########################################################################

ALIAS MESSage :PUBLish Fluidics


DEFine RinseInside $closeDelay$=0.5 $dropletTouchOff$=False $location$=Rinse $duration$ <quote>

    IF $[ "$location$" != "" ] LOCation $location$

    ### Update Rinse tank volume with dispensed volume
    SYRinge:FACTor?
    SET volumeFactor $1
    SET dispenseVolume $[ $(SYRinge:POSition?) * ${volumeFactor} ]

    ### Update Rinse Tank volume with rinse volume
    SET rate $(CONFiguration? -default=0 fluidics_specs.ini RinseRates InteriorWash)
    SET rinseVolume $[ ${rate} * max(0, $duration$) ]

    ### Wait for any previous rinse operation to complete before closing valves
    SYNC RinseClose

    TRY <quote.try>
        :FLUidics:SOLenoid:DrainPump1:CONTrol 3
        :FLUidics:SOLenoid:InteriorWashValve:CONTrol 3

        FLAG -asynchronous EmptySyringe <quote>
            MESSage "RinseInside: Emptying ${dispenseVolume}uL from syringe, rinsing for $duration$s"
            TRY <try2>
                SYRinge:POSition 0 -pattern=4
            </try2> <except2>
                SYRinge:HOME
            </except2>
        </quote>

        WAIT $duration$
	VARiable LastRinse $(:SYSTem:TIME?)

        # Close wash valve, then drain after syringe has been homed
        :FLUidics:SOLenoid:InteriorWashValve:CONTrol 0
        WAIT $closeDelay$
        SYNC EmptySyringe
        :FLUidics:SOLenoid:DrainPump1:CONTrol 0
    </quote.try> <quote.except>
        TRY ":FLUidics:SOLenoid:ExteriorWashValve:CONTrol 0" PASS
        SYNC -ignoreErrors RinseClose
        TRY ":FLUidics:SOLenoid:DrainPump1:CONTrol 0" PASS
        TRY ":FLUidics:SOLenoid:DrainPump2:CONTrol 0" PASS
        ERRor -id=$error$ $arguments$ "$message$"
    </quote.except>
    
    ### Update volume counts in System Liquid and Rinse tanks; set states
    SET totalVolume $[ ${dispenseVolume} + ${rinseVolume} ]
    :FLUidics:RemoveSystemLiquid ${rinseVolume}
    IF $[ "rinse" in "$location$".lower() ] <if.rinse>
        :FLUidics:AddRinseVolume ${totalVolume}
    </if.rinse>
    ELIF $[ "waste" in "$location$".lower() ] <if.waste>
        :FLUidics:AddWasteVolume ${totalVolume}
    </if.waste>

    #In some cases, after the rinse, a droplet forms on the tip. To remove
    #this droplet, this code touches the tip to the plastic poll extending
    #from the nozzle. The touch is done with the liquid level sensor.
    IF $dropletTouchOff$ <if.droplet>
        #Activate liquid level sense.
        :flu:motion:z:liquidlevelsensoractive 0
        :flu:motion:z:liquidlevelsensoractive 1
        
        MESSage "RinseInside: DropletTouchOff: Moving 40 counts down"
        :flu:arm:z:position -relative 40
        :flu:motion:z:liquidlevelsensoractive 0
    </if.droplet>
</quote>


DEFine RinseOutside $closeDelay$=0.5 $pullTime$=1.0 $pullRate$=50 $dropletTouchOff$=False $location$=Rinse $duration$ <quote>

    IF $[ "$location$" != "" ] <quote.if>
        LOCation $location$
        ### Determine how long to stay put, and how many steps to then move
        SET pulltime   $[ min($pullTime$, $duration$) ]
    </quote.if>
    ELSE <quote.else>
        SET pulltime 0
    </quote.else>

    SET staytime   $[ $duration$ - ${pulltime} ]
    SET pullsteps  $[ -(abs($pullRate$) * ${pulltime}) ]


    SYNC RinseClose  # Wait for any previous rinse operation to close valves

    TRY <quote.try>
        :FLUidics:SOLenoid:DrainPump2:CONTrol 3     # For now open both Drains
        :FLUidics:SOLenoid:DrainPump1:CONTrol 3
        :FLUidics:SOLenoid:ExteriorWashValve:CONTrol 3

        :FLUidics:Motion:Z:MPN 5
        Wait 0.1
        SET Vel   $(:FLUidics:Motion:Z:VEL?)
        SET iVel  $(:FLUidics:Motion:Z:IVEL?)
        FLAG -asynchronous RinsePull <quote.flag>
            MESSage "RinseOutside: Staying for ${staytime}s of total $duration$s rinse time, then pulling up ${pullsteps} steps at $pullRate$ steps/s"
            WAIT ${staytime}

            :FLUidics:Motion:Z:VEL    $pullRate$
            :FLUidics:Motion:Z:IVEL   $pullRate$
            :FLUidics:ARM:Z:POSition  ${pullsteps} -relative -pattern=5

        </quote.flag>

        WAIT $duration$    # Wait for the specified duration with valves open

        # Close wash valve, then asynchronously wait and close drains 
        :FLUidics:SOLenoid:ExteriorWashValve:CONTrol 0
        FLAG -asynchronous RinseClose <quote.flag>
            WAIT $closeDelay$
            :FLUidics:SOLenoid:DrainPump1:CONTrol 0
            :FLUidics:SOLenoid:DrainPump2:CONTrol 0     # And Close both Drains
        </quote.flag>

        SYNC RinsePull
        :FLUidics:Motion:Z:MPN 5
        Wait 0.1
        :FLUidics:Motion:Z:VEL    ${Vel}
        :FLUidics:Motion:Z:IVEL   ${iVel}
    </quote.try> <quote.except>
        TRY ":FLUidics:SOLenoid:ExteriorWashValve:CONTrol 0" PASS
        SYNC -ignoreErrors RinseClose
        TRY ":FLUidics:SOLenoid:DrainPump1:CONTrol 0" PASS
        TRY ":FLUidics:SOLenoid:DrainPump2:CONTrol 0" PASS
        ERRor -id=$error$ $arguments$ "$message$"
    </quote.except>
        
    ### Update Rinse Tank volume with rinse volume
    SET rate $(CONFiguration? -default=0 fluidics_specs.ini RinseRates ExteriorWash)
    SET rinseVolume $[ ${rate} * max(0, $duration$) ]

    ### Update volume counts in System Liquid and Rinse tanks; set states
    :FLUidics:RemoveSystemLiquid ${rinseVolume}
    IF $[ "rinse" in "$location$".lower() ] <if.rinse>
        :FLUidics:AddRinseVolume ${rinseVolume}
    </if.rinse>
    ELIF $[ "waste" in "$location$".lower() ] <if.waste>
        :FLUidics:AddWasteVolume ${rinseVolume}
    </if.waste>

    #In some cases, after the rinse, a droplet forms on the tip. To remove
    #this droplet, this code touches the tip to the plastic poll extending
    #from the nozzle. The touch is done with the liquid level sensor active.
    IF $dropletTouchOff$ <if.droplet>
        #Activate liquid level sense.
                :flu:motion:z:liquidlevelsensoractive 0
                :flu:motion:z:liquidlevelsensoractive 1

        SET offset $[($pullDistance$ * -1) + 40]
        MESSage "RinseOutside: DropletTouchOff: Moving ${offset} counts"
        :flu:arm:z:position -relative ${offset}
        :flu:motion:z:liquidlevelsensoractive 0
    </if.droplet>

</quote>


DEFine EmptySyringe $location$=Waste $closeDelay$=0.5 $force$=False <quote>
    SET position $(SYRinge:POSition?)

    IF $[ ${position} or $force$ ] <quote>
        LOCation $location$

        TRY <quote.try>
            :FLUidics:DrainPump2Open
            TRY <try2>
                SYRinge:POSition 0 -pattern=4
            </try2> <except2>
                SYRinge:HOME
            </except2>
            WAIT $closeDelay$
            :FLUidics:DrainPump2Close
        </quote.try> <quote.except>
            :FLUidics:DrainPump2Close
            ERRor -id=$error$ $arguments$ "$message$"
        </quote.except>

        ### Update Waste tank volume with dispensed volume
        SYRinge:FACTor?
        SET volumeFactor $1
        SET dispenseVolume $[ ${position} * ${volumeFactor} ]
        :FLUidics:AddWasteVolume ${dispenseVolume}
    </quote>
</quote>



DEFine HomeSyringe $force$=False <quote>
    SET Found False

    IF $[ ($force$ or not $(SYRinge:HOME?) or not $(SYRinge:HOMED?)) ] <home>
        TRY <try>
            LOCation Waste
            SET Found True
        </try> <except>
            WARNing "Could not move to 'Waste' location -- not homing syringe"
            SET Found False
        </except>
    </home>

    IF ${found} <quote.home>
        IF $(SYRinge:HOMED?) <quote>
            SYRinge:FACTor?
            SET volumeFactor $1
            SET dispenseVolume $[ $(SYRinge:POSition?) * ${volumeFactor} ]
            :FLUidics:AddWasteVolume ${dispenseVolume}
        </quote>

        TRY <quote.try>
            :FLUidics:DrainPump2Open
            MESSage "HomeSyringe: Homing"
            TRY SYRinge:HOME SYRinge:HOME SYRinge:HOME
            WAIT 1
            :FLUidics:DrainPump2Close
        </quote.try> <quote.except>
            IF ${Open} :FLUidics:DrainPump2Close
            ERRor -id=$error$ $arguments$ "$message$"
        </quote.except>
    </quote.home>
</quote>



ALIas TipCalibrationCheck :FLUidics:CalCheck1

########################################################################
### LINE PRIMING


DEFine PrimeLine <quote>
    SET IdleTime  $[ round($(:SYSTem:TIME?) - ${LastRinse:-0}, 1) ]
    SET PrimeTime $[ round(min(${PrimeMax}, ${IdleTime} / ${PrimeFactor}), 1) ]

    IF $[ ${PrimeTime} >= ${PrimeMin} ] <if>
        SET howlong ${LastRinse:+for ${IdleTime} seconds}
        SET howlong ${howlong:-since the beginning of time}

        MESSage "PrimeLine: Delivery line has been idle ${howlong}; priming for ${PrimeTime} seconds"

	RinseInside ${PrimeTime}
    </if>
</quote>

DESCribe PrimeLine <quote>
    Prime the delivery line by performing an inside tip rinse.  
    The duration of the priming depends on the elapsed time since the
    last inside rinse operation, divided by a priming factor and
    constrained by a minimum threshold and maximum priming time, all
    of which can be specified with the "PrimeLine=" command.
</quote>



DEFine PrimeLine= $min$ $max$ $factor$ <quote>
     VAR PrimeMin    $min$
     VAR PrimeMax    $max$
     VAR PrimeFactor $factor$
</quote>

DESCribe PrimeLine= <quote>

    Specify how long lines should be primed when the PrimeLines
    command is invoked (i.e. prior to SURVEY as well as prior to
    running fluidics script).

    The inputs are:

        <min>    - Only prime if the priming time exceeds this threshold.
                   Default: 0.5s

        <max>    - Maximum priming time.  Default: 30s.

        <factor> - Ratio between elapsed time since the last inside rinse
                   and the desired priming time.  
                   Default: 900 (1 second per 1/2 hour idle time).
</quote>

PrimeLine= -min=0.5 -max=30 -factor=1800


DEFine PrimeLine? <quote>
    RETurn -min=${PrimeMin} -max=${PrimeMax} -factor=${PrimeFactor}
</quote>

DESCribe PrimeLine <quote>
    Return the minmum/maximum priming time as well as the ratio between
    idle time and priming time.
</quote>



########################################################################
###  Axis test script

DEFine AxisTest $min$='' $max$='' $axis$ $count$ <quote>
    SET min $[ "$min$" or "$($axis$:REGISTERS:TRAVELLIMITNEGATIVE?)" ]
    SET max $[ "$max$" or "$($axis$:REGISTERS:TRAVELLIMITPOSITIVE?)" ]

    FLAG -asynchronous AxisTest <flag>
        REPeat -counter=count -start=1 $count$ <repeat>
            :PUBLish AxisTest "Iteration ${count} of $count$; moving $axis$ to ${min}, then ${max}..."
	    $axis$:POSition ${min}
	    $axis$:POSition ${max}
        </repeat>
    </flag>

    NEXT

    TRY <quote>
       FLAG- -ignoreMissing AxisTest
       :PUBLish AxisText "Completed; parking $axis$"
       PARK $axis$
    </quote> <except>
       IF $[ "$error$" == "Aborted" ] <if>
            PUBLish AxisTest "Aborted; parking $axis$"
            PARK $axis$
       </if> <else>
           :PUBLish AxisText "Failed; parking $axis$"
           PARK $axis$
           ERRor -id=$error$ $arguments$ <msg>$message$</msg>
       </else>
    </except>
</quote>

DEFine AxisTest~ <quote>
    FLAG- -abort -ignoreMissing AxisTest
</quote>




### Force line priming after removing system liquid tank
:STATE:TRIGGER -states=SystemLiquid:Installed -edge=Clear ForcePrime <quote>
    FLUidics:ARM:VARiable- -ignoreMissing LastRinse
</quote>